plu.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file plu.f

    
C*********************************************************************  
    
      FUNCTION plu(I,J) 
    
C...Purpose: to provide various real-valued event related data. 
      common/lujets/n,k(9000,5),p(9000,5),v(9000,5)
      SAVE /lujets/ 
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      common/ludat2/kchg(500,3),pmas(500,4),parf(2000),vckm(4,4)    
      SAVE /ludat2/ 
      dimension psum(4) 
    
C...Set default value. For I = 0 sum of momenta or charges, 
C...or invariant mass of system.    
      plu=0.    
      IF(i.LT.0.OR.i.GT.mstu(4).OR.j.LE.0) THEN 
      ELSEIF(i.EQ.0.AND.j.LE.4) THEN    
        DO 100 i1=1,n   
  100   IF(k(i1,1).GT.0.AND.k(i1,1).LE.10) plu=plu+p(i1,j)  
      ELSEIF(i.EQ.0.AND.j.EQ.5) THEN    
        DO 110 j1=1,4   
        psum(j1)=0. 
        DO 110 i1=1,n   
  110   IF(k(i1,1).GT.0.AND.k(i1,1).LE.10) psum(j1)=psum(j1)+p(i1,j1)   
        plu=sqrt(max(0.,psum(4)**2-psum(1)**2-psum(2)**2-psum(3)**2))   
      ELSEIF(i.EQ.0.AND.j.EQ.6) THEN    
        DO 120 i1=1,n   
  120   IF(k(i1,1).GT.0.AND.k(i1,1).LE.10) plu=plu+luchge(k(i1,2))/3.   
      ELSEIF(i.EQ.0) THEN   
    
C...Direct readout of P matrix. 
      ELSEIF(j.LE.5) THEN   
        plu=p(i,j)  
    
C...Charge, total momentum, transverse momentum, transverse mass.   
      ELSEIF(j.LE.12) THEN  
        IF(j.EQ.6) plu=luchge(k(i,2))/3.    
        IF(j.EQ.7.OR.j.EQ.8) plu=p(i,1)**2+p(i,2)**2+p(i,3)**2  
        IF(j.EQ.9.OR.j.EQ.10) plu=p(i,1)**2+p(i,2)**2   
        IF(j.EQ.11.OR.j.EQ.12) plu=p(i,5)**2+p(i,1)**2+p(i,2)**2    
        IF(j.EQ.8.OR.j.EQ.10.OR.j.EQ.12) plu=sqrt(plu)  
    
C...Theta and phi angle in radians or degrees.  
      ELSEIF(j.LE.16) THEN  
        IF(j.LE.14) plu=ulangl(p(i,3),sqrt(p(i,1)**2+p(i,2)**2))    
        IF(j.GE.15) plu=ulangl(p(i,1),p(i,2))   
        IF(j.EQ.14.OR.j.EQ.16) plu=plu*180./paru(1) 
    
C...True rapidity, rapidity with pion mass, pseudorapidity. 
      ELSEIF(j.LE.19) THEN  
        pmr=0.  
        IF(j.EQ.17) pmr=p(i,5)  
        IF(j.EQ.18) pmr=ulmass(211) 
        pr=max(1e-20,pmr**2+p(i,1)**2+p(i,2)**2)    
        plu=sign(log(min((sqrt(pr+p(i,3)**2)+abs(p(i,3)))/sqrt(pr), 
     &  1e20)),p(i,3))  
    
C...Energy and momentum fractions (only to be used in CM frame).    
      ELSEIF(j.LE.25) THEN  
        IF(j.EQ.20) plu=2.*sqrt(p(i,1)**2+p(i,2)**2+p(i,3)**2)/paru(21) 
        IF(j.EQ.21) plu=2.*p(i,3)/paru(21)  
        IF(j.EQ.22) plu=2.*sqrt(p(i,1)**2+p(i,2)**2)/paru(21)   
        IF(j.EQ.23) plu=2.*p(i,4)/paru(21)  
        IF(j.EQ.24) plu=(p(i,4)+p(i,3))/paru(21)    
        IF(j.EQ.25) plu=(p(i,4)-p(i,3))/paru(21)    
      ENDIF 
    
      RETURN    
      END