pyhiovly.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyhiovly.f

    
C*********************************************************************  
    
      SUBROUTINE pyhiovly(MOVLY)  
    
C...Initializes multiplicity distribution and selects mutliplicity  
C...of overlayed events, i.e. several events occuring at the same   
C...beam crossing.  
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      common/pyhipars/mstp(200),parp(200),msti(200),pari(200) 
      SAVE /pyhipars/ 
      common/pyhiint1/mint(400),vint(400) 
      SAVE /pyhiint1/ 
      dimension wti(0:100)  
      SAVE imax,wti,wts 
    
C...Sum of allowed cross-sections for overlayed events. 
      IF(movly.EQ.1) THEN   
        vint(131)=vint(106) 
        IF(mstp(132).GE.2) vint(131)=vint(131)+vint(104)    
        IF(mstp(132).GE.3) vint(131)=vint(131)+vint(103)    
        IF(mstp(132).GE.4) vint(131)=vint(131)+vint(102)    
    
C...Initialize multiplicity distribution for unbiased events.   
        IF(mstp(133).EQ.1) THEN 
          xnave=vint(131)*parp(131) 
          IF(xnave.GT.40.) WRITE(mstu(11),1000) xnave   
          wti(0)=exp(-min(50.,xnave))   
          wts=0.    
          wtn=0.    
          DO 100 i=1,100    
          wti(i)=wti(i-1)*xnave/i   
          IF(i-2.5.GT.xnave.AND.wti(i).LT.1e-6) goto 110    
          wts=wts+wti(i)    
          wtn=wtn+wti(i)*i  
  100     imax=i    
  110     vint(132)=xnave   
          vint(133)=wtn/wts 
          vint(134)=wts 
    
C...Initialize mutiplicity distribution for biased events.  
        ELSEIF(mstp(133).EQ.2) THEN 
          xnave=vint(131)*parp(131) 
          IF(xnave.GT.40.) WRITE(mstu(11),1000) xnave   
          wti(1)=exp(-min(50.,xnave))*xnave 
          wts=wti(1)    
          wtn=wti(1)    
          DO 120 i=2,100    
          wti(i)=wti(i-1)*xnave/(i-1)   
          IF(i-2.5.GT.xnave.AND.wti(i).LT.1e-6) goto 130    
          wts=wts+wti(i)    
          wtn=wtn+wti(i)*i  
  120     imax=i    
  130     vint(132)=xnave   
          vint(133)=wtn/wts 
          vint(134)=wts 
        ENDIF   
    
C...Pick multiplicity of overlayed events.  
      ELSE  
        IF(mstp(133).EQ.0) THEN 
          mint(81)=max(1,mstp(134)) 
        ELSE    
          wtr=wts*rlu(0)    
          DO 140 i=1,imax   
          mint(81)=i    
          wtr=wtr-wti(i)    
          IF(wtr.LE.0.) goto 150    
  140     CONTINUE  
  150     CONTINUE  
        ENDIF   
      ENDIF 
    
C...Format statement for error message. 
 1000 FORMAT(1x,'Warning: requested average number of events per bunch',    
     &'crossing too large, ',1p,e12.4)  
    
      RETURN    
      END