ulmass.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file ulmass.f

    
C*********************************************************************  
    
      FUNCTION ulmass(KF)   
    
C...Purpose: to give the mass of a particle/parton. 
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      common/ludat2/kchg(500,3),pmas(500,4),parf(2000),vckm(4,4)    
      SAVE /ludat2/ 
    
C...Reset variables. Compressed code.   
      ulmass=0. 
      kfa=iabs(kf)  
      kc=lucomp(kf) 
      IF(kc.EQ.0) RETURN    
      parf(106)=pmas(6,1)   
      parf(107)=pmas(7,1)   
      parf(108)=pmas(8,1)   
    
C...Guarantee use of constituent masses for internal checks.    
      IF((mstj(93).EQ.1.OR.mstj(93).EQ.2).AND.kfa.LE.10) THEN   
        ulmass=parf(100+kfa)    
        IF(mstj(93).EQ.2) ulmass=max(0.,ulmass-parf(121))   
    
C...Masses that can be read directly off table. 
      ELSEIF(kfa.LE.100.OR.kc.LE.80.OR.kc.GT.100) THEN  
        ulmass=pmas(kc,1)   
    
C...Find constituent partons and their masses.  
      ELSE  
        kfla=mod(kfa/1000,10)   
        kflb=mod(kfa/100,10)    
        kflc=mod(kfa/10,10) 
        kfls=mod(kfa,10)    
        kflr=mod(kfa/10000,10)  
        pma=parf(100+kfla)  
        pmb=parf(100+kflb)  
        pmc=parf(100+kflc)  
    
C...Construct masses for various meson, diquark and baryon cases.   
        IF(kfla.EQ.0.AND.kflr.EQ.0.AND.kfls.LE.3) THEN  
          IF(kfls.EQ.1) pmspl=-3./(pmb*pmc) 
          IF(kfls.GE.3) pmspl=1./(pmb*pmc)  
          ulmass=parf(111)+pmb+pmc+parf(113)*parf(101)**2*pmspl 
        ELSEIF(kfla.EQ.0) THEN  
          kmul=2    
          IF(kfls.EQ.1) kmul=3  
          IF(kflr.EQ.2) kmul=4  
          IF(kfls.EQ.5) kmul=5  
          ulmass=parf(113+kmul)+pmb+pmc 
        ELSEIF(kflc.EQ.0) THEN  
          IF(kfls.EQ.1) pmspl=-3./(pma*pmb) 
          IF(kfls.EQ.3) pmspl=1./(pma*pmb)  
          ulmass=2.*parf(112)/3.+pma+pmb+parf(114)*parf(101)**2*pmspl   
          IF(mstj(93).EQ.1) ulmass=pma+pmb  
          IF(mstj(93).EQ.2) ulmass=max(0.,ulmass-parf(122)- 
     &    2.*parf(112)/3.)  
        ELSE    
          IF(kfls.EQ.2.AND.kfla.EQ.kflb) THEN   
            pmspl=1./(pma*pmb)-2./(pma*pmc)-2./(pmb*pmc)    
          ELSEIF(kfls.EQ.2.AND.kflb.GE.kflc) THEN   
            pmspl=-2./(pma*pmb)-2./(pma*pmc)+1./(pmb*pmc)   
          ELSEIF(kfls.EQ.2) THEN    
            pmspl=-3./(pmb*pmc) 
          ELSE  
            pmspl=1./(pma*pmb)+1./(pma*pmc)+1./(pmb*pmc)    
          ENDIF 
          ulmass=parf(112)+pma+pmb+pmc+parf(114)*parf(101)**2*pmspl 
        ENDIF   
      ENDIF 
    
C...Optional mass broadening according to truncated Breit-Wigner    
C...(either in m or in m^2).    
      IF(mstj(24).GE.1.AND.pmas(kc,2).GT.1e-4) THEN 
        IF(mstj(24).EQ.1.OR.(mstj(24).EQ.2.AND.kfa.GT.100)) THEN    
          ulmass=ulmass+0.5*pmas(kc,2)*tan((2.*rlu(0)-1.)*  
     &    atan(2.*pmas(kc,3)/pmas(kc,2)))   
        ELSE    
          pm0=ulmass    
          pmlow=atan((max(0.,pm0-pmas(kc,3))**2-pm0**2)/    
     &    (pm0*pmas(kc,2))) 
          pmupp=atan((pm0+pmas(kc,3))**2-pm0**2)/(pm0*pmas(kc,2))   
          ulmass=sqrt(max(0.,pm0**2+pm0*pmas(kc,2)*tan(pmlow+   
     &    (pmupp-pmlow)*rlu(0))))   
        ENDIF   
      ENDIF 
      mstj(93)=0    
    
      RETURN    
      END