pyhispli.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file pyhispli.f

    
C*********************************************************************  
    
      SUBROUTINE pyhispli(KF,KFLIN,KFLCH,KFLSP)   
    
C...In case of a hadron remnant which is more complicated than just a   
C...quark or a diquark, split it into two (partons or hadron + parton). 
      dimension kfl(3)  
    
C...Preliminaries. Parton composition.  
      kfa=iabs(kf)  
      kfs=isign(1,kf)   
      kfl(1)=mod(kfa/1000,10)   
      kfl(2)=mod(kfa/100,10)    
      kfl(3)=mod(kfa/10,10) 
      kflr=kflin*kfs    
      kflch=0   
    
C...Subdivide meson.    
      IF(kfl(1).EQ.0) THEN  
        kfl(2)=kfl(2)*(-1)**kfl(2)  
        kfl(3)=-kfl(3)*(-1)**iabs(kfl(2))   
        IF(kflr.EQ.kfl(2)) THEN 
          kflsp=kfl(3)  
        ELSEIF(kflr.EQ.kfl(3)) THEN 
          kflsp=kfl(2)  
        ELSEIF(iabs(kflr).EQ.21.AND.rlu(0).GT.0.5) THEN 
          kflsp=kfl(2)  
          kflch=kfl(3)  
        ELSEIF(iabs(kflr).EQ.21) THEN   
          kflsp=kfl(3)  
          kflch=kfl(2)  
        ELSEIF(kflr*kfl(2).GT.0) THEN   
          CALL lukfdi(-kflr,kfl(2),kfdump,kflch)    
          kflsp=kfl(3)  
        ELSE    
          CALL lukfdi(-kflr,kfl(3),kfdump,kflch)    
          kflsp=kfl(2)  
        ENDIF   
    
C...Subdivide baryon.   
      ELSE  
        nagr=0  
        DO 100 j=1,3    
  100   IF(kflr.EQ.kfl(j)) nagr=nagr+1  
        IF(nagr.GE.1) THEN  
          ragr=0.00001+(nagr-0.00002)*rlu(0)    
          iagr=0    
          DO 110 j=1,3  
          IF(kflr.EQ.kfl(j)) ragr=ragr-1.   
  110     IF(iagr.EQ.0.AND.ragr.LE.0.) iagr=j   
        ELSE    
          iagr=1.00001+2.99998*rlu(0)   
        ENDIF   
        id1=1   
        IF(iagr.EQ.1) id1=2 
        IF(iagr.EQ.1.AND.kfl(3).GT.kfl(2)) id1=3    
        id2=6-iagr-id1  
        ksp=3   
        IF(mod(kfa,10).EQ.2.AND.kfl(1).EQ.kfl(2)) THEN  
          IF(iagr.NE.3.AND.rlu(0).GT.0.25) ksp=1    
        ELSEIF(mod(kfa,10).EQ.2.AND.kfl(2).GE.kfl(3)) THEN  
          IF(iagr.NE.1.AND.rlu(0).GT.0.25) ksp=1    
        ELSEIF(mod(kfa,10).EQ.2) THEN   
          IF(iagr.EQ.1) ksp=1   
          IF(iagr.NE.1.AND.rlu(0).GT.0.75) ksp=1    
        ENDIF   
        kflsp=1000*kfl(id1)+100*kfl(id2)+ksp    
        IF(kflin.EQ.21) THEN    
          kflch=kfl(iagr)   
        ELSEIF(nagr.EQ.0.AND.kflr.GT.0) THEN    
          CALL lukfdi(-kflr,kfl(iagr),kfdump,kflch) 
        ELSEIF(nagr.EQ.0) THEN  
          CALL lukfdi(10000+kflsp,-kflr,kfdump,kflch)   
          kflsp=kfl(iagr)   
        ENDIF   
      ENDIF 
    
C...Add on correct sign for result. 
      kflch=kflch*kfs   
      kflsp=kflsp*kfs   
    
      RETURN    
      END