klu.f

Go to the documentation of this file. Or view the newest version in sPHENIX GitHub for file klu.f

    
C*********************************************************************  
    
      FUNCTION klu(I,J) 
    
C...Purpose: to provide various integer-valued event related data.  
      common/lujets/n,k(9000,5),p(9000,5),v(9000,5)
      SAVE /lujets/ 
      common/ludat1/mstu(200),paru(200),mstj(200),parj(200) 
      SAVE /ludat1/ 
      common/ludat2/kchg(500,3),pmas(500,4),parf(2000),vckm(4,4)    
      SAVE /ludat2/ 
    
C...Default value. For I=0 number of entries, number of stable entries  
C...or 3 times total charge.    
      klu=0 
      IF(i.LT.0.OR.i.GT.mstu(4).OR.j.LE.0) THEN 
      ELSEIF(i.EQ.0.AND.j.EQ.1) THEN    
        klu=n   
      ELSEIF(i.EQ.0.AND.(j.EQ.2.OR.j.EQ.6)) THEN    
        DO 100 i1=1,n   
        IF(j.EQ.2.AND.k(i1,1).GE.1.AND.k(i1,1).LE.10) klu=klu+1 
        IF(j.EQ.6.AND.k(i1,1).GE.1.AND.k(i1,1).LE.10) klu=klu+  
     &  luchge(k(i1,2)) 
  100   CONTINUE    
      ELSEIF(i.EQ.0) THEN   
    
C...For I > 0 direct readout of K matrix or charge. 
      ELSEIF(j.LE.5) THEN   
        klu=k(i,j)  
      ELSEIF(j.EQ.6) THEN   
        klu=luchge(k(i,2))  
    
C...Status (existing/fragmented/decayed), parton/hadron separation. 
      ELSEIF(j.LE.8) THEN   
        IF(k(i,1).GE.1.AND.k(i,1).LE.10) klu=1  
        IF(j.EQ.8) klu=klu*k(i,2)   
      ELSEIF(j.LE.12) THEN  
        kfa=iabs(k(i,2))    
        kc=lucomp(kfa)  
        kq=0    
        IF(kc.NE.0) kq=kchg(kc,2)   
        IF(j.EQ.9.AND.kc.NE.0.AND.kq.NE.0) klu=k(i,2)   
        IF(j.EQ.10.AND.kc.NE.0.AND.kq.EQ.0) klu=k(i,2)  
        IF(j.EQ.11) klu=kc  
        IF(j.EQ.12) klu=kq*isign(1,k(i,2))  
    
C...Heaviest flavour in hadron/diquark. 
      ELSEIF(j.EQ.13) THEN  
        kfa=iabs(k(i,2))    
        klu=mod(kfa/100,10)*(-1)**mod(kfa/100,10)   
        IF(kfa.LT.10) klu=kfa   
        IF(mod(kfa/1000,10).NE.0) klu=mod(kfa/1000,10)  
        klu=klu*isign(1,k(i,2)) 
    
C...Particle history: generation, ancestor, rank.   
      ELSEIF(j.LE.16) THEN  
        i2=i    
        i1=i    
  110   klu=klu+1   
        i3=i2   
        i2=i1   
        i1=k(i1,3)  
        IF(i1.GT.0.AND.k(i1,1).GT.0.AND.k(i1,1).LE.20) goto 110 
        IF(j.EQ.15) klu=i2  
        IF(j.EQ.16) THEN    
          klu=0 
          DO 120 i1=i2+1,i3 
  120     IF(k(i1,3).EQ.i2.AND.k(i1,1).GT.0.AND.k(i1,1).LE.20) klu=klu+1    
        ENDIF   
    
C...Particle coming from collapsing jet system or not.  
      ELSEIF(j.EQ.17) THEN  
        i1=i    
  130   klu=klu+1   
        i3=i1   
        i1=k(i1,3)  
        i0=max(1,i1)    
        kc=lucomp(k(i0,2))  
        IF(i1.EQ.0.OR.k(i0,1).LE.0.OR.k(i0,1).GT.20.OR.kc.EQ.0) THEN    
          IF(klu.EQ.1) klu=-1   
          IF(klu.GT.1) klu=0    
          RETURN    
        ENDIF   
        IF(kchg(kc,2).EQ.0) goto 130    
        IF(k(i1,1).NE.12) klu=0 
        IF(k(i1,1).NE.12) RETURN    
        i2=i1   
  140   i2=i2+1 
        IF(i2.LT.n.AND.k(i2,1).NE.11) goto 140  
        k3m=k(i3-1,3)   
        IF(k3m.GE.i1.AND.k3m.LE.i2) klu=0   
        k3p=k(i3+1,3)   
        IF(i3.LT.n.AND.k3p.GE.i1.AND.k3p.LE.i2) klu=0   
    
C...Number of decay products. Colour flow.  
      ELSEIF(j.EQ.18) THEN  
        IF(k(i,1).EQ.11.OR.k(i,1).EQ.12) klu=max(0,k(i,5)-k(i,4)+1) 
        IF(k(i,4).EQ.0.OR.k(i,5).EQ.0) klu=0    
      ELSEIF(j.LE.22) THEN  
        IF(k(i,1).NE.3.AND.k(i,1).NE.13.AND.k(i,1).NE.14) RETURN    
        IF(j.EQ.19) klu=mod(k(i,4)/mstu(5),mstu(5)) 
        IF(j.EQ.20) klu=mod(k(i,5)/mstu(5),mstu(5)) 
        IF(j.EQ.21) klu=mod(k(i,4),mstu(5)) 
        IF(j.EQ.22) klu=mod(k(i,5),mstu(5)) 
      ELSE  
      ENDIF 
    
      RETURN    
      END